How to I make a variable that displays a single random letter a-z.

for example

I want to do something like this

echo %RANDOM:~-1%

but instead display something like this

echo a
echo q
echo w
echo y
echo h

by doing this

echo %RandomLetter%
echo %RandomLetter%
echo %RandomLetter%
echo %RandomLetter%
echo %RandomLetter%


@echo off
REM Setup random source
REM Put this before you you start using
REM random letters
setlocal enabledelayedexpansion
set alphabet=abcdefghijklmnopqrstuvwxyz
set randsource=
REM Append alphabet as many times as you like
set copies=100
for /l %%N in (1,1,%copies%) do set randsource=!randsource!%alphabet%
set /a maxnum=26*%copies%

REM Get a random character
SET /A rnum=%RANDOM%*%maxnum%/32768+1
set randletter=!randsource:~%rnum%,1!
echo %randletter%
Or use a VBScript one-liner:

@echo off
set lowercase=96
set uppercase=64
set casetype=%uppercase%
echo randomize:wscript.echo chr(Int((26)*Rnd+1)+%casetype%) > randletter.vbs
for /f %%A in ('cscript //nologo randletter.vbs') do set randletter=%%A
echo %randletter% Here's a way to do it. Much fun.


Code: [Select]@echo off
:: Echos a random letter
set randletter=call set /a r=%%random%% %%%% 26 ^& setlocal enabledelayedexpansion ^& set "alphabet=abcdefghijklmnopqrstuvwxyz" ^& call echo %%alphabet:~!r!,1%%^& endlocal

%randletter%
%randletter%
%randletter%
%randletter%
%randletter%
%randletter%
%randletter%
%randletter%
%randletter%
%randletter%
%randletter%
Quote from: Salmon Trout on March 23, 2016, 02:07:20 AM

@echo off
REM Setup random source
REM Put this before you you start using
REM random letters
setlocal enabledelayedexpansion
set alphabet=abcdefghijklmnopqrstuvwxyz
set randsource=
REM Append alphabet as many times as you like
set copies=100
for /l %%N in (1,1,%copies%) do set randsource=!randsource!%alphabet%
set /a maxnum=26*%copies%

REM Get a random character
SET /A rnum=%RANDOM%*%maxnum%/32768+1
set randletter=!randsource:~%rnum%,1!
echo %randletter%

Randomized alphabet string 26 chars long, (no repeats)

Code: [Select]@echo off
REM 65 for upper case, 97 for lower case
set CaseType=97
> Randalphabet.vbs echo randomize timer
>> Randalphabet.vbs echo RandAlphabet=""
>> Randalphabet.vbs echo Do
>> Randalphabet.vbs echo randchar = Chr(Int(26*Rnd+%CaseType%))
>> Randalphabet.vbs echo If Instr(RandAlphabet, randchar) = 0 Then RandAlphabet = RandAlphabet ^& randchar
>> Randalphabet.vbs echo if len(RandAlphabet) = 26 Then exit Do
>> Randalphabet.vbs echo Loop
>> Randalphabet.vbs echo wscript.echo RandAlphabet
REM -----------------------------------------------

REM Here you use it
for /f "delims=" %%A in ('cscript //nologo Randalphabet.vbs') do set Randalphabet=%%A
echo %Randalphabet%
Examples

Code: [Select]cjdmtelkufvywozsnbghxairqp
pojqhbyftgweviadlxzrsncumk
ayoublqmvzdhfkxpiwcngsterj

Have you noticed what happens if you delete or comment out the randomize timer line in the vbs?

the only thing that i realized is that it goes to an error on second run due to the ">" sign not being a ">>", what exactly is happening?

Comment out the VBS line being written like this (that's a single quote just before the randomize keyword)

(etc)
> Randalphabet.vbs echo 'randomize timer
(etc)

It would be nice if Zask could tell us why he wants to do this.
If it is just for the fun of doing a task in DOS the hard way, that is OK.
But if Zask needs a quick and effective solution to a piratical problem, he might say so.

Here is why I ask. He is using a Random generator to make a sequence that is not random. He wants a re-ordered sequence of the Alphabet. It is a table where are letters are present, but not in an obvious order. Such tables do not need the random generator. Such are used in some types of encryption methods. And it can be done in batch, but if anybody finds the code your method is no longer a secret.

Simple number sequnces.
https://www.mathsisfun.com/numberpatterns.html
This can be one way of making a unusual sequence. But you can also do it by hand and get good results. The idea is a foundation on which to build. You can add complexity to it later.
Partial example: (only 8 items to show the idea.)
Code: [Select]1 2 3 4 5 6 7 8 < order
A B C D E F G H
5 2 7 4 1 6 3 8 < scramble

Thank you that is helpful, but the problem isnt scrambling the code pattern, although yall did help me fix a problem that i was currently having. the problem now is that when i try to decrpyt the code, when i use variables like "%var%", they display as actual text instead of what the variable is suppose to display and when i encrypt the code, i use the "!" sign in "!var!", but they wont send out to the "!" sign to the encrypted text file because the max setlocal recursion is reached.