I'm currently trying to make a tedious task I have to do daily much easier, and I figured I may as WELL attempt to fully automate it.
I am currently attempting to automate/schedule an Outlook 2003 Macro I wrote to download all of the files off of specific email messages by creating another macro in the ThisOutlookSession area...

However, I do not know VBA very well.

Does anyone know how I might be able to accomplish this?
Thank you in advance for your help.

So far, the only Idea I have had is the following (using a couple of test subroutines):

Private Sub Application_Startup()

test

End Sub

Sub test()

Dim CurrTime As String
Dim CurrDay As String

CurrDay = Format("ddmmyy", Date)

CurrTime = DatePart("h", TIME)

If CurrTime = "11" Then
testSend
End If

'INSERT CODE TO PAUSE MACRO WITHOUT HANGING APPLICATION
test

End Sub
Sub testSend()

SendMessage "Test Success", "The Macro Appears to Work...For Now", "[emailprotected]"

End Sub

Sub SendMessage(Subj As String, Message As String, Receivers As String)

Dim toSend As MailItem

Set toSend = CreateItem(olMailItem)
toSend.BodyFormat = olFormatPlain
toSend.Subject = Subj
toSend.Body = Message
toSend.To = Receivers
toSend.Send

SendMessage_exit:
Set toSend = Nothing
Exit Sub

End Sub


Do you have any ideas as to how I might tell the macro to wait an hour before checking the time again without causing the system to hang?Add a new module (Insert->Module)

Paste this:

Code: [Select]Option Explicit
Declare Function SetTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerfunc As Long) As Long
Declare Function KillTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long) As Long

Public TimerID As Long 'Need a timer ID to eventually turn off the timer. If the timer ID <> 0 then the timer is running

Public Sub ActivateTimer(ByVal nMinutes As Long)
nMinutes = nMinutes * 1000 * 60 'SetTimer accepts milliseconds- convert to minutes.
If TimerID <> 0 Then Call DeactivateTimer 'make sure there isn't already a timer.
TimerID = SetTimer(0, 0, nMinutes, AddressOf TriggerTimer)
If TimerID = 0 Then
MsgBox "Timer failure."
End If
End Sub

Public Sub DeactivateTimer()
Dim lSuccess As Long
lSuccess = KillTimer(0, TimerID)

End Sub

Public Sub TriggerTimer(ByVal hwnd As Long, ByVal uMsg As Long, ByVal idevent As Long, ByVal Systime As Long)
static lastday as integer
if lastday <> Day(Now) And Hour(Now)=11 Then
testsend
lastday = day(now)
End If
End Sub


Sub testSend()

SendMessage "Test Success", "The Macro Appears to Work...For Now", "[emailprotected]"

End Sub

Sub SendMessage(Subj As String, Message As String, Receivers As String)

Dim toSend As MailItem

Set toSend = CreateItem(olMailItem)
toSend.BodyFormat = olFormatPlain
toSend.Subject = Subj
toSend.Body = Message
toSend.To = Receivers
toSend.Send

SendMessage_exit:
Set toSend = Nothing
End Sub



Now for your Application_Startup and Shutdown events:

Code: [Select]Private Sub Application_Quit()
If TimerID <> 0 Then Call DeactivateTimer 'Do NOT skip this step!
End Sub

Private Sub Application_Startup()
MsgBox "Activating the Timer."
Call ActivateTimer(10) 'Set timer for 10 min
End Sub

Hope this helps. Basically, what it does is create a windows Timer to fire every 10 minutes , which ends up calling the "TriggerTimer()" function. Here I just plopped in your testsend and sendmessage routines and call testsend from the timer routine, after running a few checks to make sure that the hour is eleven and we haven't already sent it today. (the "static" variable keeps it's value between invocations) Thank you so much!

This works perfectly! Quote from: southpaw63119 on July 16, 2010, 08:59:27 AM

Thank you so much!

This works perfectly!

Would you recommend setting the value to 0, or is there another way I can do it?

(sorry about all of this...)