1. Test.vdf (before)

Code: [Select]{
{
Section 1
}
{
Section 2
}
{
Section 3
}
{
Section 4
}
}

2. Script

Code: [Select]@echo off
setlocal enabledelayedexpansion
for /f "delims==" %%A in ('dir /b /s S:\*.vdf') do (
set filepath=%%~dpA
set filename=%%~nA
set fileExtn=%%~XA
)
Echo Found file
Echo Path %filepath%
Echo Name %filename%%fileExtn%
cd /d "%filepath%"
set linecount=0
for /f "delims=" %%A in ('type "%filename%%fileExtn%"') do set /a linecount+=1
if exist "%filename%-new%fileExtn%" del "%filename%-new%fileExtn%"
set linenumber=0
for /f "delims=" %%A in ('type "%filename%%fileExtn%"') do (
set /a linenumber+=1
if !linenumber! equ %linecount% (

echo { >> "%filename%-new%fileExtn%"
echo Section 5 >> "%filename%-new%fileExtn%"
echo } >> "%filename%-new%fileExtn%"
echo } >> "%filename%-new%fileExtn%"

) else (
echo %%A >> "%filename%-new%fileExtn%"
)
)
echo Rename
echo ren "%filename%%fileExtn%" "%filename%-OLD%fileExtn%"
ren "%filename%%fileExtn%" "%filename%-old%fileExtn%"
echo ren "%filename%-new%fileExtn%" "%filename%%fileExtn%"
ren "%filename%-new%fileExtn%" "%filename%%fileExtn%"
echo done

1. Test.vdf (after)

Code: [Select]{
{
Section 1
}
{
Section 2
}
{
Section 3
}
{
Section 4
}
{
Section 5
}
}